Classic toolbars (including address bar) and explorer bars restored

{Spoiler}

#NoEnv
#NoTrayIcon
SendMode Input

Init:
;; Path to start button picture
ButtonPressed = C:\Classic\StartButton W98 Plum\StartPressed.png
ButtonDepressed = C:\Classic\StartButton W98 Plum\StartDepressed.png
ex = ahk_class Shell_TrayWnd ahk_exe explorer_old.exe

;; Uncomment these 2 lines if you want to use Win-X
; Run, rundll32 TaskbarContextMenuTweaker.dll`,Release
; Run, rundll32 TaskbarContextMenuTweaker.dll`,Inject
;; Hide Win10 taskbar
WinHide ahk_class Shell_TrayWnd ahk_exe explorer.exe
;; Start ROS explorer
Run, C:\Classic\StartButton2000\explorer_old.exe
WinWaitActive, %ex%
;; Hide ROS start button
Control, Disable,, Button1, %ex%
Control, Hide,, Button1, %ex%
;; Fix for Win10 glowing border on taskbar
WinSet, Style, +0xC00000, %ex%
WinSet, Style, -0xC00000, %ex%

;; Define new GUI
Gui, +hwndChild -Caption -Border +alwaysontop -Resize
DllCall("uxtheme.dll\SetThemeAppProperties", "UInt", 0)
;; Picture instead of button because AHK is weird
Gui, Add, Picture, x0 y0 vStart1 gStartPress, %ButtonDepressed%
Gui, Show, w56 h26
;; Set parent of GUI to ROS taskbar
Parent := WinExist("ahk_class Shell_TrayWnd ahk_exe explorer_old.exe" pid)
DllCall("SetParent", "ptr", Child, "ptr", Parent)
;; Start button position and size
WinMove, ahk_id %child%,, 1, 1, 52, 22
;; Awful workaround part one
SetTimer, IsStartOpen, 50
Return

StartPress:
;; Open ClassicShell start menu by emulating Win key press
Send, {LWin}
SetTimer, IsStartOpen, Off
;; Change button picture to pressed
GuiControl,,Start1,%ButtonPressed%
GuiControl, -g +gStartDepress, Start1,
SetTimer, FixButton, 50
Return

StartDepress:
SetTimer, FixButton, Off
;; Change button picture to depressed
GuiControl,,Start1,%ButtonDepressed%
GuiControl, -g +gStartPress, Start1,
SetTimer, IsStartOpen, 50
Return

FixButton:
;; If button is pressed but start menu is closed, depress the start button
If !WinExist("ahk_class ClassicShell.CMenuContainer") {
Goto, StartDepress
}
Return

IsStartOpen:
;; Awful workaround part two
If WinExist("ahk_class ClassicShell.CMenuContainer") {
GuiControl,,Start1,%ButtonPressed%
GuiControl, -g +gStartDepress, Start1,
SetTimer, IsStartOpen, Off
SetTimer, FixButton, 50
}
Return

GuiContextMenu:
;; Opens Win-X menu by default
Send, {LWin Down}{x}{LWin Up}
Return